Creare rettangoli in AutoCAD a partire da dimensioni riportate in una tabella excel

Marcochiara

Utente registrato
Professione: studente
Software: autocad
Regione: puglia
#1
Buongiorno,

Avendo a disposizione una tabella excel di due colonne, in cui sono riportate l'altezza e la larghezza di centinaia di rettangoli, vorremmo creare un disegno CAD di tutti i suddetti rettangoli. È possibile importare il file excel in AutoCAD per automatizzare il disegno dei rettangoli, evitando così di doverli disegnare uno ad uno?

Nello specifico utilizziamo AutoCAD per Mac (versioni 2014, 2017 o 2018)

Grazie infinite,
Marco e Chiara
 

GP.

Utente Senior
Professione: Nientologo
Software: uozapp
Regione: Vercelli
#2
Ok per le dimensioni, ma il problema è dire ad Autocad dove disegnarli.
Prendi spunto da questa discussione (vedi la gif), prova ad impostare il punto d'inserimento aggiungendo alla coordinata x, di volta in volta, la dimensione della base, avresti in AutoCAD tutti i rettangoli uno di fianco all'altro.
Sperando che la procedura funzioni su mac
 

Legs

Utente Standard
Professione: ingegnere strutturista
Software: Autocad
Regione: Provincia Milano
#3
Io farei così:
esporto tutti i dati numerici in un semplice file di testo creando una cosa del tipo:
30.0 40.3
120.0 50.0
130.2 30.0
...
fai attenzione a sostituire alla virgola il punto. Si fa con la ricerca e sostituzione in automatico.
a questo punto utilizzi un piccolo autolisp come questo (è molto artigianale. Da per scontato tante cose. Ricordati di disattivare gli osnap prima di usarlo):

Codice:
(defun c:disegna( / x0 y0 deltax f lst b h pt1 pt2)
    (setq f (open "dati.txt" "r"))
    
    (setq x0 0.0
          y0 0.0
          deltax 5.0)
        
    (while (setq riga (read-line f))
        (setq lst (read (strcat "(" riga ")")))
        (setq b (car lst))
        (setq h (cadr lst))
        (setq pt1 (list x0 y0))
        (setq pt2 (list (+ x0 b) (+ y0 h)))
        (command "rectangle" pt1 pt2)
        (setq x0 (+ x0 b deltax)))
    (close f))
Il programma è un po' rozzo e non fa alcun controllo sull'esistenza del file etc...
Ho fatto delle ipotesi del tipo: i dati vengono memorizzati nel file dati.txt all'interno della cartella Documenti.

carica il file disegna.lsp in autocad (vai in tools - Load Application per farlo) poi scrivi disegna nella finestra dei comandi di autocad (ricordati di disattivare gli osnap usando F3).

P.S.
Consiglio di usare BBedit con l'evidenziazione dei comandi autolisp. È molto comodo per scrivere il codice.
Comunque ti allego il codice e il file di esempio che ho usato. Mi raccomando di mettere il file coi dati nella cartella Documenti se no non funziona.
Il programma l'ho testato con Autocad for Mac 2019 e funziona perfettamente.
La variabile deltax contiene la distanza tra i rettangoli. Modificane pure il valore come credi.
 

Allegati

Legs

Utente Standard
Professione: ingegnere strutturista
Software: Autocad
Regione: Provincia Milano
#4
P.S.
Mi sono accorto di aver dimenticato il trattino di sottolineature davanti a rectangle.
Se qualcuno volesse utilizzare il programma con una versione in lingua diversa dall'inglese si ricordi di aggiungerlo o di cambiare il comando rectangle con il corrispondente nella sua lingua.
Altra cosa: il file dati.txt potete metterlo dove volete ma ricordatevi di utilizzare il percorso per raggiungerlo.
Ad esempio se volessi metterlo sulla scrivania del Mac dovrei usare un nome completo:
/Users/nomeutente/Desktop/dati.txt
dove chiaramente al posto di nomeutente va messo il proprio.
 

gelyparis

Utente Junior
Professione: insegnante
Software: autocad, 3ds max, Photoshop
Regione: veneto
#5
Devi impostare il foglio di excel in questo modo:
formato celle: testo, altrimenti le virgole creano strani effetti in excel
prima cella es. A1, metti il nome del comando rectang o _rectang
seconda cella, B1, la prima coppia di coordinate separate dalla virgola, es. 100,200
terza cella, C1, la seconda coppia di coordinate, es. 550.10,1000.50
e ripeti l'operazione sulle righe successive per ogni rettangolo.
Se hai già le coordinate inserite nel file di excel e sono in singole celle, le devi unire a coppie (coordinata x,y primo punto, coord. x,y secondo punto) con la funzione "concatena"
Eventualmente vedi questo mio video che spiega un'operazione simile.
Poi copia tutto e vai nella linea di comando di Autocad e incolla, dovrebbero comparire tutti i rettangoli e,
se le coordinate sono riferite allo zero dell'UCS corrente, come credo, questi si posizioneranno automaticamente nello spazio di autocad.
 

Legs

Utente Standard
Professione: ingegnere strutturista
Software: Autocad
Regione: Provincia Milano
#6
Ho voluto rivedere il mio codice e ho tolto l'inutile y0 che avevo inserito perché avevo immaginato di poter muovermi anche secondo la y. In realtà non serve. Allineo tutto rispetto a y=0.0 e amen.
Ho inserito anche un controllo sull'esistenza del file e tolta la necessità di disattivare gli osnap. Adesso non serve più. Puoi lasciarli attivi.
Ho messo in evidenza il valore del gap così uno può modificarlo come gli pare.
Avrei potuto metterlo come parametro della funzione ma preferisco così. Se no va a finire che uno si annoia a doverlo reinserire ogni volta.

Allego il nuovo codice:
Codice:
; disegno di rettangoli allineati alla base

(defun c:disegna( / x0 deltax f lst b h pt1 pt2)

    (setq deltax 5.0) ; gap tra i rettangoli - modificarlo a piacere

    (if (setq f (open "dati.txt" "r"))

        (progn
            (setq modo (getvar "OSMODE"))
            (setvar "OSMODE" 0)
            (setq x0 0.0)
            (while (setq riga (read-line f))
                (setq lst (read (strcat "(" riga ")"))
                       b (car lst)
                       h (cadr lst)
                       pt1 (list x0 0.0)
                       pt2 (list (+ x0 b) h))
                (command "_rectangle" pt1 pt2)
                (setq x0 (+ x0 b deltax)))
            (close f)
            (setvar "OSMODE" modo)
            (print "comando terminato"))

        (print "file non trovato"))
    (princ))
Peccato che non si possa colorarlo come nell'editor.
Allego comunque il nuovo codice.

Ciao. Il codice l'ho ritestato e funziona perfettamente.
 

Allegati