Ansys.com


Risultati da 1 a 1 di 1
  1. #1
    Bannato
    Iscritto dal
    2007
    Messaggi
    1683
    Professione
    *
    Regione
    Lombardia
    Software
    AutoCAD

    Predefinito Centroide di un'area delimitata da una polilinea

    Inserisce un punto nel centroide delle geometrie selezionate (le polilinee devono essere chiuse)



    Codice:
    (defun c:polycen (/ polySet polyList Model newPl obArr newReg newPt) 
      (princ "\n*** Select closed polylines *** ") 
      (if 
      (setq polySet(ssget '((0 . "LWPOLYLINE")))) 
       (progn 
         (setq polyList(mapcar 'vlax-ename->vla-object 
                                (vl-remove-if 'listp 
                                  (mapcar 'cadr(ssnamex polySet)))) 
          Model(vla-get-ModelSpace 
             (vla-get-ActiveDocument 
               (vlax-get-acad-object))) 
          ); end setq 
         (foreach p polyList 
           (if(= :vlax-true(vla-get-Closed p)) 
        (progn 
           (setq newPl(vla-copy p) 
            obArr(vlax-make-safearray vlax-vbObject '(0 . 0)) 
            ); end setq 
           (vlax-safearray-put-element obArr 0 newPl) 
           (setq newReg(car(vlax-safearray->list 
               (vlax-variant-value 
                 (vla-AddRegion Model obArr)))) 
                 newPt(vlax-3d-point 
              (append 
              (vlax-safearray->list 
                (vlax-variant-value 
             (vla-get-Centroid newReg)))(list 0.0))) 
        ); end setq 
           (vla-AddPoint Model newPt) 
           (vla-delete newPl)(vla-delete newReg) 
           ); end progn 
        ); end if 
           ); end foreach 
         ); end progn 
      (princ "\n*** Notning closed polylines selected! *** ") 
      ); end if 
      (princ) 
      ); end of c:polycen
    (vl-load-com)
    segnalato da antoniovinci
    Ultima modifica di arri; 22-08-2008 alle 23: 55


  • Discussioni Simili

    1. Stampa in pdf di un'area selezionata
      Di Lubracali nel forum VBA per Autocad
      Risposte: 0
      Ultimo Messaggio: 09-01-2011, 15: 56
    2. Risposte: 9
      Ultimo Messaggio: 15-06-2010, 12: 08
    3. Rilevare blocchi all'interno di un'area limitata
      Di piratabobo nel forum VBA per Autocad
      Risposte: 6
      Ultimo Messaggio: 29-07-2009, 11: 02
    4. Apriamo un'area per Auton?
      Di CADCAMdoctor nel forum CAM forum generale
      Risposte: 17
      Ultimo Messaggio: 03-04-2009, 23: 07
    5. Stimare un'area sul disegno
      Di ocraM999 nel forum Revit
      Risposte: 5
      Ultimo Messaggio: 08-06-2008, 18: 46

    Segnalibri

    Segnalibri

    Permessi di Scrittura

    • Tu non puoi inviare nuove discussioni
    • Tu non puoi inviare risposte
    • Tu non puoi inviare allegati
    • Tu non puoi modificare i tuoi messaggi
    •  



    CAD3D.it - la community dei progettisti