Pagina 6 di 8 PrimaPrima ... 45678 UltimaUltima
Risultati da 51 a 60 di 73
  1. #51
    Utente Standard L'avatar di Catafratto
    Iscritto dal
    2011
    Messaggi
    809
    Professione
    Disegnatore/progettista
    Regione
    Veneto
    Software
    Inventor 2016

    Predefinito

    Citazione Originariamente Scritto da callaghan Visualizza Messaggio
    scusate, ma alla fine qualcuno è riuscito ad esportare in pdf un'intera cartella di idw già esistenti??
    Prova questo: ti compare una riga di input, inserisci il percorso della cartella dove vuoi fare il lavoro, apre ed esporta tutti gli idw che contiene: poichè ho buttato giù le cose in fretta fatti delle prove su cartelle copiate, prima, che non si sa mai ! Le numerose (= 1) prove che ho fatto funzionavano. NON aggiungere il backSlash a fine percorso al momento dell'input sennò non va.

    La macro da lanciare è DirIDW

    Fammi sapere


    Codice:
    
    Public Sub DirIDW()
    
        Dim myDir As String
        Dim myName As String
        
        ' Richiede il percorso della cartella
        myDir = InputBox("Inserisci il percorso dei disegni (termina SENZA \)", "Richiesta percorso files")
        
    
        ' Visualizza i nomi in c:\ che rappresentano directory.
        myName = Dir(myDir & "\*.idw", vbNormal)   ' Recupera la prima voce.
        Debug.Print "Inizio ciclo"
        Dim i As Integer
        Do While myName <> ""    ' Avvia il ciclo.
            Debug.Print i, myDir & "\" & myName
            ExportDirToDWG_PDF (myDir & "\" & myName)
            myName = Dir    ' Legge la voce successiva.
            i = i + 1
        Loop
    
    End Sub
    
    
    Public Sub ExportDirToDWG_PDF(drawing As String)
        
        ' Obtain reference to drawing
        Dim oDoc As Document
        Set oDoc = ThisApplication.Documents.Open(drawing)
        
        
        Dim fn As String
        Dim DWGfn As String
        Dim PDFfn As String
        
        ' Generate the file names
        fn = oDoc.FullFileName
        DWGfn = Strings.Left(fn, Len(fn) - 4) & ".dwg"
        PDFfn = Strings.Left(fn, Len(fn) - 4) & ".pdf"
        
        
        ' Get the DWG translator Add-In.
        Dim DWGAddIn As TranslatorAddIn
        Set DWGAddIn = ThisApplication.ApplicationAddIns.ItemById("{C24E3AC2-122E-11D5-8E91-0010B541CD80}")
    
        ' Get the DXF translator Add-In.
        Dim DXFAddIn As TranslatorAddIn
        Set DXFAddIn = ThisApplication.ApplicationAddIns.ItemById("{C24E3AC4-122E-11D5-8E91-0010B541CD80}")
        
        ' Get the PDF translator Add-In.
        Dim PDFAddIn As TranslatorAddIn
        Set PDFAddIn = ThisApplication.ApplicationAddIns.ItemById("{0AC6FD96-2F4D-42CE-8BE0-8AEA580399E4}")
        
        Dim strIniFile As String
        
        
        ' Common init
        ' Create a Context object
        Dim oContext As TranslationContext
        Set oContext = ThisApplication.TransientObjects.CreateTranslationContext
        oContext.Type = kFileBrowseIOMechanism
          
        ' Create a NameValueMap object
        Dim oOptions As NameValueMap
        Set oOptions = ThisApplication.TransientObjects.CreateNameValueMap
    
        ' Create a DataMedium object
        Dim oDataMedium As DataMedium
        Set oDataMedium = ThisApplication.TransientObjects.CreateDataMedium
    
        ' ---------------------------------------------------------------------------
        ' DWG
        ' -------------------------------
        
        ' Check whether the translator has 'SaveCopyAs' options
        If DWGAddIn.HasSaveCopyAsOptions(oDoc, oContext, oOptions) Then
            ' File with exportation options
            strIniFile = "C:\tempDWGOut.ini"
            ' Create the name-value that specifies the ini file to use.
            oOptions.Value("Export_Acad_IniFile") = strIniFile
        End If
    
        'Set the destination file name
        oDataMedium.filename = DWGfn
    
    
        'Publish document.
        Call DWGAddIn.SaveCopyAs(oDoc, oContext, oOptions, oDataMedium)
        
        ' -------------------------------
        ' FINE DWG
        ' ---------------------------------------------------------------------------
      
        
        ' ---------------------------------------------------------------------------
        ' PDF
        ' -------------------------------
    
        ' Check whether the translator has 'SaveCopyAs' options
        If PDFAddIn.HasSaveCopyAsOptions(oDoc, oContext, oOptions) Then
    
            ' Options for drawings...
    
            oOptions.Value("All_Color_AS_Black") = 0
    
            'oOptions.Value("Remove_Line_Weights") = 0
            'oOptions.Value("Vector_Resolution") = 400
            'oOptions.Value("Sheet_Range") = kPrintAllSheets
            'oOptions.Value("Custom_Begin_Sheet") = 2
            'oOptions.Value("Custom_End_Sheet") = 4
        End If
    
        'Set the destination file name
        oDataMedium.filename = PDFfn
    
    
        'Publish document.
        Call PDFAddIn.SaveCopyAs(oDoc, oContext, oOptions, oDataMedium)
        ' -------------------------------
        ' FINE PDF
        ' ---------------------------------------------------------------------------
        
        oDoc.Close (True)
    End Sub
    Spesso astuzia ed intelligenza sono molto più efficaci dell'ottusa forza bruta: ma non ho proprio tempo di cercare qualcun alltro...

  2. #52
    Utente Standard
    Iscritto dal
    2008
    Messaggi
    692
    Professione
    mah!
    Regione
    .
    Software
    Inv + SW(purtroppo)

    Predefinito

    Provato e funziona.
    Però se cerco di salvare il default.ivb ( nel quale avevo incollato il dirIDW ) mi dice :

    msg.JPG

    che può essere ?

    Mille grazie.

  3. #53
    Utente Standard L'avatar di Catafratto
    Iscritto dal
    2011
    Messaggi
    809
    Professione
    Disegnatore/progettista
    Regione
    Veneto
    Software
    Inventor 2016

    Predefinito

    Citazione Originariamente Scritto da MauroM Visualizza Messaggio
    Provato e funziona.
    Però se cerco di salvare il default.ivb ( nel quale avevo incollato il dirIDW ) mi dice :

    msg.JPG

    che può essere ?

    Mille grazie.
    Non ho idea... sparo a caso:
    siete in più persone in ufficio e condividete il file default.ivb? Solo il primo ad aver aperto una sessione di Inventor può salvarlo
    Hai usato l'editor VBA di Inventor per fare la cosa?
    Ci sono password/diritti di amministratore/ecc sul disco dove lavori?
    Ti dà lo stesso errore anche se provi a scrivere qualcosa e salvare, tipo
    "Public sub Pippo()
    End sub"

    E soprattutto, hai riavviato il computer e riprovato?
    Spesso astuzia ed intelligenza sono molto più efficaci dell'ottusa forza bruta: ma non ho proprio tempo di cercare qualcun alltro...

  4. #54
    Utente Standard
    Iscritto dal
    2008
    Messaggi
    692
    Professione
    mah!
    Regione
    .
    Software
    Inv + SW(purtroppo)

    Predefinito

    Citazione Originariamente Scritto da Catafratto Visualizza Messaggio
    Non ho idea... sparo a caso:
    siete in più persone in ufficio e condividete il file default.ivb? Solo il primo ad aver aperto una sessione di Inventor può salvarlo...
    proprio questo. Grazie.

  5. #55
    Utente Junior
    Iscritto dal
    2013
    Messaggi
    67
    Professione
    disegnatore
    Regione
    Piemonte (TO)
    Software
    Inventor 2014

    Predefinito

    Appena riesco provo in ufficio
    grazie!

  6. #56
    Utente Junior
    Iscritto dal
    2013
    Messaggi
    67
    Professione
    disegnatore
    Regione
    Piemonte (TO)
    Software
    Inventor 2014

    Predefinito

    Purtroppo non va...
    Al primo avvio della macro converte tutti gli .idw in .dwg e tutti gli .idw in .pdf tranne 2
    al secondo tentativo i .dwg sempre OK e i .pdf tutti tranne 4
    al terzo tentativo i .dwg sempre OK e i .pdf tutti tranne 6
    e così via..
    sembra che ci sia qualche contatore che ad ogni lancio della macro tolga 2 file da convertire
    da notare che gli .idw si aprono automaicamente tutti durante la macro, ma alcuni non vengono convertiti in .pdf
    boh???
    purtroppo non capisco una mazza di VB.. vedo se qualche collega...

  7. #57
    Utente Standard L'avatar di Catafratto
    Iscritto dal
    2011
    Messaggi
    809
    Professione
    Disegnatore/progettista
    Regione
    Veneto
    Software
    Inventor 2016

    Predefinito

    Citazione Originariamente Scritto da callaghan Visualizza Messaggio
    Purtroppo non va...
    Al primo avvio della macro converte tutti gli .idw in .dwg e tutti gli .idw in .pdf tranne 2
    al secondo tentativo i .dwg sempre OK e i .pdf tutti tranne 4
    al terzo tentativo i .dwg sempre OK e i .pdf tutti tranne 6
    e così via..
    sembra che ci sia qualche contatore che ad ogni lancio della macro tolga 2 file da convertire
    da notare che gli .idw si aprono automaicamente tutti durante la macro, ma alcuni non vengono convertiti in .pdf
    boh???
    purtroppo non capisco una mazza di VB.. vedo se qualche collega...

    - Hai provato ad aprire i disegni che danno problemi e ad usare la versione "manuale" della macro per vedere che succede? Non mi viene in mente proprio niente...
    - Qualcun altro ha provato e ha avuto problemi simili?

    - Hai riavviato tutto? E' un toccasana collaudato, vale sempre la pena provare
    Spesso astuzia ed intelligenza sono molto più efficaci dell'ottusa forza bruta: ma non ho proprio tempo di cercare qualcun alltro...

  8. #58
    Utente Standard L'avatar di Catafratto
    Iscritto dal
    2011
    Messaggi
    809
    Professione
    Disegnatore/progettista
    Regione
    Veneto
    Software
    Inventor 2016

    Predefinito

    Ho provato su un paio di cartelle, a me funziona correttamente...
    Boh!
    Spesso astuzia ed intelligenza sono molto più efficaci dell'ottusa forza bruta: ma non ho proprio tempo di cercare qualcun alltro...

  9. #59
    Utente Junior
    Iscritto dal
    2013
    Messaggi
    67
    Professione
    disegnatore
    Regione
    Piemonte (TO)
    Software
    Inventor 2014

    Predefinito

    devo ancora provare a riavviare il PC, Inventor ovviamente l'ho riavviato più volte
    il fatto strano è che al primo giro va bene e converte tutti gli .idw, poi ogni volta che riprovi si perde i primi 2 files della lista
    esempio: 21 files ok al primo giro, poi 19, 17, 15, 13.......
    se riprovo su un'altra cartella riparte bene, poi di nuovo lo stesso errore
    E' vero che mi basterebbe che funzionasse bene la prima volta x convertire in blocco tutti i disegni, poi eventuali modifiche/aggiunte dovrei gestirle singolarmente.
    Proverò ancora, grazie comunque

  10. #60
    Utente Junior
    Iscritto dal
    2013
    Messaggi
    67
    Professione
    disegnatore
    Regione
    Piemonte (TO)
    Software
    Inventor 2014

    Predefinito

    Ho provato a riavviare il PC... Miracolo!! Funziona!! (x adesso.... )
    Ho anche suddiviso la macro: una x i pdf e una x i dwg

    Grazie mille !!


  • Pagina 6 di 8 PrimaPrima ... 45678 UltimaUltima

    Discussioni Simili

    1. Esportazione Modello FEM da CATIA a ".nas"
      Di SeM_Mario nel forum CAE/FEM/CFD forum generale
      Risposte: 0
      Ultimo Messaggio: 05-09-2014, 15: 32
    2. Risposte: 0
      Ultimo Messaggio: 17-04-2014, 02: 38
    3. Risposte: 7
      Ultimo Messaggio: 27-03-2013, 14: 32
    4. Risposte: 7
      Ultimo Messaggio: 28-02-2013, 00: 55
    5. quotatura "automatica"
      Di spider916 nel forum CATIA V5 CATDrawing
      Risposte: 6
      Ultimo Messaggio: 23-05-2011, 10: 01

    Segnalibri

    Segnalibri

    Permessi di Scrittura

    • Tu non puoi inviare nuove discussioni
    • Tu non puoi inviare risposte
    • Tu non puoi inviare allegati
    • Tu non puoi modificare i tuoi messaggi
    •  





    CAD3D.it - la community dei progettisti